# INITIALIZE
# for Proteopedia (applet)
if (_applet) { script "/wiki/images/d/de/MPSupportVersion01.spt" }
# for Projection (application)
else { script MPSupportVersion01.spt }

initializeBeforeEachCycle

# DEFINE VARIABLES & VALUES
spinDefault = true;
delayFive = 5.0 # 1.0 for testing -- 5.0 for production
delayTwo = 2.0 # 0.5 for testing -- 2.0 for production
initialProteinZoom = 100
if (jmolSmall)
{
	initialProteinZoom = 90
	set antialiasdisplay true
}

# LOAD MOLECULE (restores windowcentered)
if (_applet)
{
	load "/wiki/images/f/fc/2hu4_chain_a.pdb"
}
else
{
	load tamiflu.pdb
}

# INITIALIZE MOLECULE (LIGHT CPK COLORS ETC.)
initializeMolecule

# BACKGROUND
#background black # black is the default

# BANNER AT TOP (bannerMessage2 is defined in MPSupportVersion01.spt)
showBannerAcrossTop("Tamiflu, an anti-influenza drug, could save you from H1N1!", bannerMessage2)

# TAMIFLU STICKS
center [g39]
restrict [g39]
wireframe 0.3
spacefill off

# LABEL TAMIFLU
labelAtomWithPointer("g39.c91","Tamiflu Drug","white")

# ELEMENT COLOR KEY
var elist = array("C", "O", "N")
elementColorKey(elist)

# ZOOM UP (Use zoom loop instead of Jmol's zoomto
# because zoomto "fights" with user rotation)
zoomRotatableTo(500)

spinOn

delay @delayFive # spinning continues during a delay

# GROW DRUG SPACEFILL
select [g39]
growSpacefill()

delay @delayFive

# RENDER PROTEIN AS CARTOON
select protein
color yellow
color translucent -1
ssbonds off
cartoon

delay @delayTwo

# ZOOM OUT
zoomRotatableTo(400)

# PROTEIN COLOR KEY (ECHO AT TOP CENTER)
set echo in_echo [50 85 %]
set echo in_echo center
# color echo translucent -1 gives an opaque font
color echo translucent 2 yellow
background echo black
background echo translucent 6
font echo @echoFontSize sansserif bold
echo "   Influenza Neuraminidase Is The   |    Protein Target Inhibited By The Drug    "

delay @delayTwo

# ZOOM OUT (Use zoom loop instead of zoomto b/c zoomto "fights" with user rotation)
zoomRotatableTo(120)

delay @delayFive

# GROW PROTEIN SPACEFILL
select protein
growSpacefill()

delay @delayFive

message "Jmol Script Execution Completed"